Új hozzászólás Aktív témák

• #15931 Mutt senior tag repvez #15913

  Új Válasz 2012-12-30 19:01:15 #15931

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz repvez #15913 üzenetére

  Szia,

  Ezek a képletek fognak jól műkődni:

  =OFSZET($L$3;HOL.VAN($D$3;$L$4:$L$12;0);HOL.VAN($C$3;$M$3:$Q$3;0))

  Az eltolás (ofszet) úgy műkődik, hogy egy referencia céllától (esetedben a keresendő táblázat origójától L3-tól) adott SOR-t és OSZLOP-ot mozog. Tehát előbb le-fel és utána balra-jobbra lehet innen mozogni. A fenti két HOL.VAN kiszámolja, hogy mennyit kell le, majd jobbra menni.

  Másik megoldás a VKERES-sel:

  =VKERES($C$3;$M$3:$Q$12;HOL.VAN($D$3;$L$4:$L$12;0)+1;0)

  Tehát itt előbb megnézzük, hogy melyik oszlopban (pl. alacsony) kell lemenni hány sort (mivel az első sor maga a fejléc ezért +1-el kell lejjebb mennünk.

  .. vagy FKERES-sel

  =FKERES($D$3;$L$3:$Q$12;HOL.VAN($C$3;$M$3:$Q$3;0)+1;0)

  .. vagy INDEX-el

  =INDEX($M$4:$Q$12;HOL.VAN($D$3;$L$4:$L$12;0);HOL.VAN($C$3;$M$3:$Q$3;0))

  Itt a logika hasonló az ELTOLÁS-hoz, csak itt egy tömbből (ez az adatsorod fejléc nélkül, vagyis M4:Q12 tartomány) az adott SOR és OSZLOP elemét választjuk ki.

  Végül egy elvetemült megoldás:

  =INDIREKT("S"&HOL.VAN($D$3;L4:L12;0)+CELLA("sor";$L$3)&"O"&HOL.VAN($C$3;$M$3:$Q$3;0)+CELLA("oszlop";$L$3);0)

  Ez R1C1 formátumban kiszámolja a metszeti cella kordinátáit és visszaadja az ott lévő értéket.

  A sok megoldás közül javasolt az FKERES/VKERES vagy INDEX-es megoldás, mivel azokban nincs volatile függvény így kicsit gyorsabbak és kevesebb erőforrást használnak. Az ELTOLÁS, INDIREKT és CELLA függvényeket a munkalap minden egyes változásakor az Excel újraszámolja (kivétel ha ez az opció ki van kapcsolva).

  üdv.

Új hozzászólás Aktív témák