Új hozzászólás Aktív témák

• #54620 Mutt senior tag underdark #54617

  Új Válasz 2025-08-22 02:16:26 #54620

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Mutt

  senior tag

  válasz underdark #54617 üzenetére

  Szia,

  Kimutatást javasoljuk erre.
  Az újabb Excel-ekben képlettel is lehetséges már.
  
  E2-ben a képlet: =KIMUTATÁS.ALAP.SZERINT(Table1[Name];Table1[Year];Table1[ASC];SZUM;0;0;;0)

  Van egy másik képletem is de sokkal hosszabb.
  

  =LET(nevek;SORBA.RENDEZ(EGYEDI(Table1[Name]));
  evek;SORBA.RENDEZ(EGYEDI(Table1[Year]));
  sorszam;SORSZÁMLISTA(DARAB2(nevek));
  ertekek;REDUCE(TRANSZPONÁLÁS(evek);sorszam;LAMBDA(s;c;FÜGG.HALMOZÁS(s;TRANSZPONÁLÁS(SZUMHATÖBB(Table1[ASC];Table1[Name];INDEX(nevek;c);Table1[Year];evek)))));
  VÍZSZ.HALMOZÁS(FÜGG.HALMOZÁS("";nevek);ertekek))

  A képletben az "ertekek" sorban van a lényeg, ami a SZUMHATÖBB segítségével kiszámolja mindegyik névhez és évhez az értéket. A REDUCE-t arra használom, hogy a kapott értékeket "egymásra tegyem" (függőleges halmozás), mert ezt tudom majd a munkalapra kiírni. A végén még az elejére teszem a neveket.

  üdv

• #54619 Fferi50 Topikgazda underdark #54617

  Új Válasz 2025-08-21 07:36:54 #54619

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz underdark #54617 üzenetére

  Szia!
  Még egy lehetőség: Kimutatást készítesz, ahol a name lesz a sorcimke, a year az oszlopcimke és az asc oszlop összege lesz az értékek mezőben. Mivel minden név és év egy számot tartalmaz, így a kimutatás névsorosan fogja az éves értékeket mutatni.
  Az összegző sorokat megjelenítését ki kell venned a kimutatásból (kimutatáson állva - Tervezés - Végösszegek - kikapcsolva sorokban és oszlopokban).
  Ha új sort vittél be a táblázatba, akkor a kimutatást is frissítened kell, ennyi a hátránya.
  Üdv.

• #54618 Fferi50 Topikgazda underdark #54617

  Új Válasz 2025-08-20 23:23:10 #54618

  Új hozzászólás

  Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra

  Privát üzenet küldése

  

  Fferi50

  Topikgazda

  válasz underdark #54617 üzenetére

  Szia!
  Ettől tartottam... (nem a kuszábbá válástól, hanem az adatok ilyen struktúrájától).
  Ebben az esetben nem használható gazdaságosan az XKERES függvény, mivel mindig csak egy találatot ad vissza.
  Mivel legalább 2021-es Exceled van, ezért használni tudod az EGYEDI és a SZŰRŐ függvényeket.
  Az A1 : C5 tartományt átalakítottam táblázattá, hogy a táblázatos címzést tudjam használni.
  Az éveket az I1 cellától a következő képlettel kaphatod meg:
  =TRANSZPONÁLÁS(EGYEDI(Táblázat1[year]))  
  Az E1 cellába írtam be a kívánt nevet.
  Ezután az I2 cellában a képlet (ezt látod a képen is):
  =SZŰRŐ(Táblázat1[[#Mind];[asc]];(Táblázat1[[#Mind];[name]]=$E$1)*(Táblázat1[[#Mind];[year]]=I$1);0)
  Ezt a képletet másolni és beilleszteni kell a mellette levő cellákba (nem pedig egérrel húzni!) és akkor megfelelően működik.
  Figyelned kell a $ jelekre a cella címzésekben!
  Remélem, tudod alkalmazni a saját táblázatodra. Ha nem sikerülne, küldd el privát üziben.
  Kiegészítés: Ha a neveket is egy listában szeretnéd látni, akkor a képlet a képen a H2 cellába:
  =EGYEDI(Táblázat1[name])
  
  Az I2 cella képlete pedig a következő:
  =SZŰRŐ(Táblázat1[[#Mind];[asc]];(Táblázat1[[#Mind];[name]]=$H2)*(Táblázat1[[#Mind];[year]]=I$1);0)
  A nevek helyzetének figyelembe vételével változott.
  A képlet az I2 cella mellett levő cellákba másolás - beillesztés továbbra is a megfelelő mód, utána lefelé mindhárom oszlop egyszerre húzható.

  Üdv.

Új hozzászólás Aktív témák